home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD020b.dsk / BRIAN'S THEME.bas < prev    next >
BASIC Source File  |  2003-06-12  |  2KB  |  36 lines
  1. 10  HOME : REM  CLEAR THE TEXT WINDOW
  2. 11  TEXT : POKE 216,0: REM  TURN OFF ONERR
  3. 15  VTAB 7: HTAB 15: PRINT "BRIAN'S  THEME"
  4. 20  VTAB 9: HTAB 17: PRINT "    BY"
  5. 25  VTAB 11: HTAB 16: PRINT "BRIAN HOWARD"
  6. 30  VTAB 15: PRINT "   COPYRIGHT 1979,  APPLE COMPUTER INC."
  7. 35  VTAB 23: HTAB 9: PRINT "PRESS RETURN TO CONTINUE...";
  8. 40  GET A$: IF A$ < > CHR$(13)  THEN 40
  9. 80  HOME : REM  CLEAR THE TEXT AREA
  10. 100  VTAB 22: REM   MOVE CURSOR TO MIDDLE
  11. 120  HGR : REM  SET HIGH RESOLUTION GRAPHICS MODE
  12. 140 A =  RND(1) *279: REM  PICK AN X FOR "CENTER"
  13. 160 B =  RND(1) *159: REM  PICK A Y FOR "CENTER"
  14. 180 I% = ( RND(1) *4) +2: REM  PICK A STEP SIZE
  15. 190  HOME : VTAB 22
  16. 200  HTAB 15: PRINT "STEPPING BY ";I%
  17. 210  VTAB 24: PRINT "      <PRESS THE 'ESC' KEY TO STOP>";
  18. 220  FOR X = 0 TO 278  STEP I%: REM  STEP THROUGH X VALUES
  19. 240  FOR S = 0 TO 1: REM  2 LINES, FROM X AND X+1
  20. 260  HCOLOR= 3 *S: REM  FIRST LINE BLACK, NEXT WHITE
  21. 280  REM  DRAW LINE THROUGH "CENTER" TO OPPOSITE SIDE
  22. 300  HPLOT X +S,0 TO A,B TO 279 -X -S,159
  23. 310  IF  PEEK( -16384) = 155  THEN 31111
  24. 320  NEXT S,X
  25. 340  FOR Y = 0 TO 158  STEP I%: REM  STEP THROUGH Y VALUES
  26. 360  FOR S = 0 TO 1: REM  2 LINES, FROM Y AND Y+1
  27. 380  HCOLOR= 3 *S: REM  FIRST LINE BLACK, NEXT WHITE
  28. 400  REM  DRAW LINE THROUGH "CENTER" TO OPPOSITE SIDE
  29. 420  HPLOT 279,Y +S TO A,B TO 0,159 -Y -S
  30. 430  IF  PEEK( -16384) = 155  THEN 31111
  31. 440  NEXT S,Y
  32. 460  FOR PAUSE = 1 TO 1500: NEXT PAUSE: REM  DELAY
  33. 480  GOTO 120: REM  DRAW A NEW PATTERN
  34. 31111  POKE  -16298,0: REM  TURN OFF HI-RES
  35. 31112  POKE  -16388,0: REM   CLEAR KBD STROBE
  36. 31115  TEXT : CALL  -936: TEXT : END